What is the Perl version of a Python iterator?

There’s a good practical example here and a PDF article here… but I’m too rusty in Perl to try to implement your challenge directly (as you’ll see, both the example and the approach in the PDF use a less direct approach).

There is a similar method to produce a Iterator / Generator, but it is not a “first class citizen” as it is on Python.

In Perl, if you do not see what you want (after a MANDATORY trip to CPAN FIRST!), you can roll your own that is similar to a Python iterator based on Perl closures and an anonymous subroutine.

Consider:

use strict; use warnings;

sub fibo {
    my ($an, $bn)=(1,0);
    my $mag=(shift || 1);
    my $limit=10**$mag;
    my $i=0;

    return sub {
        ($an, $bn)=($bn, $an+$bn);      
        return undef if ($an >=$limit || wantarray );
        return $an;
    }
}

my $num;
my $iter=fibo(15);
while (defined($num=$iter->()) ) { printf "%17dn", $num; }

The sub fibo maintains a Perl closure that allows persistent variables to be maintained. You can do the same by having a module, similar to C / C++. Inside fibo an anonymous subroutine does the work of returning the next data item.

To quote from the Perl Bible “You will be miserable until you learn the difference between scalar and list context” — p 69 (A highly recommended book btw…)

In this case, the annon sub only returns a single value. The only looping mechanism that I know of in Perl that can work in scalar context is while; The others try to fill the list before proceeding I think. Therefor, if you called the anon sub in list context, it will dutifully return the next fibonacci number, unlike Python’s for iterators, and the loop would terminate. That is why I put the return undef if .... wantarray because it does not work in list context as written.

There are ways to fix that. Indeed, you can write subroutines that act like map foreach etc but it is not as straightforward as Python’s yield. You will need an additional function to use inside a foreach loop. The tradeoff is the Perl approach has tremendous power and flexibility.

You can read more about Perl iterators in Mark Jason Dominus’ excellent book “Higher Order Perl” Chapter 4 is all about Interators brian d foy also has an excellent article on Interators in the Perl Review.

The concept of an iterator is a little different in Perl. You basically want to return a one-use subroutine “closed” over the persistent variables.

use bigint;
use strict;
use warnings;

sub fibonacci {
    my $limit = 10**( shift || 0 );
    my ( $a, $b ) = ( 0, 1 );
    return sub { 
        return if $a > $limit;
        ( my $r, $a, $b ) = ( $a, $b, $a + $b );
        return $r;
    };
}
my $fit = fibonacci( 15 );
my $n = 0;
while ( defined( my $f = $fit->())) { 
     print "F($n): $fn";
     $n++;
}

And if you don’t like the while loop, then here is two shots at some syntactic sugar, which basically accomplish an each-item loop.:

sub iterate ($$) {
    my $iter   = shift;
    my $action = shift;
    while ( defined( my $nextval = $iter->())) { 
        local *_ = $nextval;
        $action->( $_ );
    }
    return;
}

iterate fibonacci( 15 ) => sub { print "$_n"; };

sub iter (&$) { 
    my $action = shift;
    my $iter   = shift;
    while ( defined( my $nextval = $iter->())) { 
        local *_ = $nextval;
        $action->( $_ );
    }
    return;
}

iter { print "$_n" } fibonacci( 15 );

The excellent Higher-Order Perl book (available for free at the specified link) contains a lot of information on related topics, and in particular has a whole chapter on iterators. By “higher order” the author implies using Perl’s abilities as a functional language with first-class functions to implement all kinds of cool stuff. It really is a very good book – I read most of it, and the chapters on iterators and streams are terrific. I highly recommend to at least skim through it if you plan to write Perl code.

In this case, memoization can be used.

use strict;
use warnings;

use Memoize;
memoize('fib');

foreach my $i (1..15) {
  print "$i -> ",fib($i),"n";
}

sub fib {
  my $n = shift;
  return $n if $n < 2;
  fib($n-1) + fib($n-2);
}

Here is a response tailored to conform closely to the question as originally posed.

Any perl module that implements lazy lists (e.g. List::Gen, Memoize, etc.) and also lets you supply your own generator subroutine (I don’t mean ‘generator’ as in Python) will allow you to do as shown in this example. Here the module that lazily produces the list is called Alef.

#!/usr/bin/perl -w

use strict; use warnings; 
use Alef;

my $fibo;

BEGIN {

    my ($a, $b) = (0, 1);

    $fibo = sub {
        ($a, $b) = ($b, $a+$b);
        $a;
    }
}

my $fibonacci = new Alef($fibo);

foreach my $number ($fibonacci->take(15)){ print $number . "n"; }

Here is the output:

[spl@briareus ~]$ ./fibo.pl
0
1
1
2
3
5
8
13
21
34
55
89
144
233
377

There is nothing magical happening behind the scenes with the lazy list module used here. This is what Alef’s take subroutine looks like.

sub take {

    my ($self,$n) = (@_);

    my @these = ();

    my $generator = $self->{'generator'};
    for (1..$n){
        push(@these,$self->{'this'});
        $self->{'this'} = &$generator($self->{'this'});
    }
    @these;
}

There are a few iterator/generator modules on CPAN that would help here. Here is your example directly translated to the Coro::Generator module:

use 5.016;
use warnings;
use Coro::Generator;

sub gen_fibonacci {
    my $mag = shift;
    generator {
        my ($a, $b) = (0, 1);
        while ($a <= 10 ** $mag) {
            yield $a;
            ($a, $b) = ($b, $a + $b);
        }   
        yield undef;  # stop it!
    };  
}   

my $fibonacci = gen_fibonacci(15);

while (defined (my $number = $fibonacci->())) {
    printf "%17dn", $number;
}